Tema: [SOLUCIONADO] ¿Cómo modificar la leyenda y la posición de un gráfico con macros?

Hola a todos los foreros de ayudasexcel, espero que me puedan ayudar con un problemilla que encuentro al crear un grafico con macros.

Mi problema consiste en que al crear un grafico con macros no me modifica la leyenda del grafico como yo quiero que quede (la que aparece al lado derecho con los detalles del grafico), la modificación que quiero hacerle es cambiar el tamaño del texto de la leyenda, lo raro es que en el codigo aparece dicha accion, pero no ocurre.

Ademas le indico que cambie la posicion original del grafico, que es donde lo deja el excel por defecto al crearlo y en vez de eso lo reubique en una posicion mas armoniosa con respecto a lo que estoy mostrando, pero ahi me encuentro con otro problema, ya que si el usuario por ejemplo se encuentra con la hoja abierta en la coordenada A1, la posicion del grafico queda bien, pero si esta en una coordenada mas abajo en la hoja (o mas a la derecha, da igual), por ejemplo X100, entonces el grafico queda cerca de esa coordenada y no donde yo quiero que quede, que seria cerca de la coordenada A1.

Segun entiendo, al reubicar el grafico lo que ocurre es que reposiciona tantos puntos a la derecha y tanto puntos hacia arriba (y asi en cualquier direccion) como se lo indica el codigo, pero desde la posicion original, que seria el centro de la pantalla, independiente de la coordenada en que se encuentre el usuario, lo cual genera mi problema, ya que para solucionarlo, creo yo, deberia indicar con alguna especie de codigo que indique la posicion en la que debe estar la pantalla antes de crear el grafico, para asi no tener problemas, pero no se si exista o sea posible.

Otro punto que creo que es importante es que yo al momento de generar la macro desactivo las alertas y las actualizaciones de la hoja para que no se vea lo que esta ocurriendo en la macro.

Bueno desde ya agradezco su ayuda y espero me puedan ayudar.

PD: Se me olvidaba adjuntar el codigo de ejemplo, que similar al que uso y esta comentado, para que lo revisen y puedan ver mi problema.

Hola Natanael,

para añadir un gráfico en una hoja de pronto sea más fácil si añades como un objeto directamente en la hoja en lugar de crearlo y luego moverlo a la hoja en la que lo quieres, Prueba este código.... left es la distancia a la izquierda de la hoja en la que lo quieres ubicar, width el ancho, top la distancia desde la parte superior de la hoja y height el alto:

Código:

Sub prueba()
    
    With ActiveSheet.ChartObjects.Add(Left:=100, Width:=375, Top:=75, Height:=225).Chart
        .SetSourceData Source:=Sheets("Hoja1").Range("A1:B10")
        .ChartType = xl3DPie
        .Legend.Font.Size = 8
    End With

End Sub

Hola de nuevo, me alegra haber ayudado en algo .

Iniciado por Natanael

...Aunque trate de agregarle a ese mismo codigo que al momento de crear el grafico tambien le pusiera los bordes redondos, cambiara el color de fondo y todo lo que hacia en el grafico anterior....

Esto puede ser una forma de hacerlo:

Código:

Sub prueba()

    Dim Nombre As String
    
    Nombre = "Graf" & Sheets("Hoja1").Shapes.Count
    
    With ActiveSheet.ChartObjects.Add(Left:=100, Width:=375, Top:=75, Height:=225)
        .Name = Nombre
        .Border.Weight = 2
        .Border.LineStyle = -1
        With .Chart
            .SetSourceData Source:=Sheets("Hoja1").Range("A1:B10")
            .ChartType = xl3DPie
            .Legend.Font.Size = 8
            With .ChartArea.Fill
                .TwoColorGradient Style:=msoGradientDiagonalUp, Variant:=2
                .Visible = True
                .ForeColor.SchemeColor = 8
                .BackColor.SchemeColor = 2
            End With
        End With
    End With
    
    With Sheets("Hoja1").DrawingObjects(Nombre)
        .RoundedCorners = True
        .Shadow = True
    End With

End Sub

puedes encontrar algunos códigos muy buenos sobre gráficas en la página de John Peltier, uno de los gurús en gráficas de Excel: http://peltiertech.com/Excel/